1SUMMARY = "iSCSI daemon and utility programs"
2DESCRIPTION = "Open-iSCSI project is a high performance, transport \
3independent, multi-platform implementation of RFC3720. The iscsi package \
4provides the server daemon for the iSCSI protocol, as well as the utility \
5programs used to manage it. iSCSI is a protocol for distributed \
6disk access using SCSI commands sent over Internet Protocol networks."
7HOMEPAGE = "http://www.open-iscsi.com/"
8LICENSE = "GPL-2.0-only & LGPL-2.1-only"
9SECTION = "net"
10DEPENDS = "openssl flex-native bison-native open-isns util-linux kmod"
11DEPENDS += "${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'systemd', '', d)}"
12
13LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
14
15SRCREV ?= "ee575fd19429ec6dc24b49f2ce3822b4a01f57de"
16
17SRC_URI = "git://github.com/open-iscsi/open-iscsi;branch=master;protocol=https \
18           file://0001-Makefile-Do-not-set-Werror.patch \
19           file://initd.debian \
20           file://99_iscsi-initiator-utils \
21           file://iscsi-initiator \
22           file://iscsi-initiator.service \
23           file://iscsi-initiator-targets.service \
24           file://set_initiatorname \
25           "
26S = "${WORKDIR}/git"
27
28inherit update-rc.d systemd autotools pkgconfig
29
30EXTRA_OECONF = " \
31    --target=${TARGET_SYS} \
32    --host=${BUILD_SYS} \
33"
34
35EXTRA_OECONF += "${@bb.utils.contains('DISTRO_FEATURES', 'systemd', '', '--without-systemd NO_SYSTEMD=1',     d)}"
36
37EXTRA_OEMAKE = ' \
38    OS="${TARGET_SYS}" \
39    TARGET="${TARGET_OS}" \
40    BASE="${prefix}" \
41    MANDIR="${mandir}" \
42    OPTFLAGS="-DNO_SYSTEMD ${CFLAGS}" \
43    PKG_CONFIG="${STAGING_BINDIR_NATIVE}/pkg-config" \
44'
45
46
47do_configure () {
48    cd ${S}/iscsiuio ; autoreconf --install; ./configure ${EXTRA_OECONF}
49}
50
51do_compile () {
52    # Make sure we DO NOT regenerate prom_lex.c.
53    if [ -f ${S}/utils/fwparam_ibft/prom_lex.l ]; then
54        mv ${S}/utils/fwparam_ibft/prom_lex.l ${S}/utils/fwparam_ibft/prom_lex.l.unused
55    fi
56    oe_runmake -C ${S} ${EXTRA_OEMAKE} user
57}
58
59do_install () {
60    #install necessary directories
61    install -d ${D}${sbindir} \
62        ${D}${sysconfdir}/init.d \
63        ${D}${sysconfdir}/iscsi \
64        ${D}${localstatedir}/lib/iscsi/nodes \
65        ${D}${localstatedir}/lib/iscsi/send_targets \
66        ${D}${localstatedir}/lib/iscsi/static \
67        ${D}${localstatedir}/lib/iscsi/isns \
68        ${D}${localstatedir}/lib/iscsi/slp \
69        ${D}${localstatedir}/lib/iscsi/ifaces \
70        ${D}${libdir} \
71        ${D}${mandir}/man8
72
73    install -p -m 755 ${S}/usr/iscsid ${S}/usr/iscsiadm \
74        ${S}/utils/iscsi-iname \
75        ${S}/usr/iscsistart ${D}/${sbindir}
76
77    cp -dR ${S}/libopeniscsiusr/libopeniscsiusr.so* ${D}${libdir}
78    install -p -m 644 ${S}/doc/iscsiadm.8 ${S}/doc/iscsid.8 ${D}/${mandir}/man8
79    install -p -m 644 ${S}/etc/iscsid.conf ${D}${sysconfdir}/iscsi
80    install -p -m 755 ${WORKDIR}/initd.debian ${D}${sysconfdir}/init.d/iscsid
81
82    sed -i -e "s:= /sbin/iscsid:= ${sbindir}/iscsid:" ${D}${sysconfdir}/iscsi/iscsid.conf
83
84    if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
85        install -d ${D}${sysconfdir}/tmpfiles.d
86        echo "d /run/${BPN}/lock - - - -" \
87                     > ${D}${sysconfdir}/tmpfiles.d/iscsi.conf
88        install -d ${D}/etc/default/
89        install -p -m 755 ${WORKDIR}/iscsi-initiator ${D}${sysconfdir}/default/
90
91        install -d ${D}${systemd_unitdir}/system/
92        install -m 0644 ${WORKDIR}/iscsi-initiator.service \
93                        ${WORKDIR}/iscsi-initiator-targets.service \
94                        ${D}${systemd_unitdir}/system/
95        install -d ${D}${nonarch_libdir}/iscsi
96        install -m 0755 ${WORKDIR}/set_initiatorname ${D}${nonarch_libdir}/iscsi
97    else
98        install -d ${D}/etc/default/volatiles
99        install -m 0644 ${WORKDIR}/99_iscsi-initiator-utils ${D}/etc/default/volatiles
100    fi
101}
102
103pkg_postinst:${PN}() {
104    if [ "x$D" = "x" ]; then
105        if [ -e /etc/init.d/populate-volatile.sh ]; then
106            /etc/init.d/populate-volatile.sh update
107        elif command -v systemd-tmpfiles >/dev/null; then
108            systemd-tmpfiles --create ${sysconfdir}/tmpfiles.d/iscsi.conf
109        fi
110    fi
111}
112
113SYSTEMD_SERVICE = " iscsi-initiator.service iscsi-initiator-targets.service "
114INITSCRIPT_NAME = "iscsid"
115INITSCRIPT_PARAMS = "start 30 1 2 3 4 5 . stop 70 0 1 2 3 4 5 6 ."
116
117FILES:${PN} += "${nonarch_libdir}/iscsi"
118