xref: /OK3568_Linux_fs/yocto/meta-openembedded/meta-networking/recipes-connectivity/vpnc/vpnc_0.5.3.bb (revision 4882a59341e53eb6f0b4789bf948001014eff981) 
1SUMMARY = "A client for the Cisco3000 VPN Concentrator"
2HOMEPAGE = "http://www.unix-ag.uni-kl.de/~massar/vpnc/"
3AUTHOR = "Maurice Massar vpnc@unix-ag.uni-kl.de"
4SECTION = "net"
5LICENSE = "GPL-2.0-or-later"
6LIC_FILES_CHKSUM = "file://COPYING;md5=173b74cb8ac640a9992c03f3bce22a33"
7
8DEPENDS += "libgcrypt"
9
10PV .= "r550-2jnpr1"
11SRCREV = "b1243d29e0c00312ead038b04a2cf5e2fa31d740"
12SRC_URI = "git://github.com/ndpgroup/vpnc;branch=master;protocol=https \
13           file://long-help \
14           file://default.conf \
15           file://0001-search-for-log-help-in-build-dir.patch \
16           file://0002-Fix-vpnc-install-for-cross-compile.patch \
17           file://0003-error.h-is-specific-to-glibc-on-linux.patch \
18           file://0004-Use-pkgconfig-instead-of-libgcrypt-config.patch \
19           file://0005-include-sys-ttydefaults.h-for-CEOT-definition.patch \
20           file://0006-sysdep-Add-header-include-sequence-to-adjust-for-mus.patch \
21           file://0007-add-error-API-when-error.h-is-not-on-platform.patch \
22           file://0008-include-sysdep.h-before-net-if_tun.h.patch \
23           file://0009-reduce-lifetime-value.patch \
24           "
25
26PACKAGECONFIG ?= "gnutls"
27
28PACKAGECONFIG[gnutls] = ",,gnutls"
29PACKAGECONFIG[openssl] = ",,openssl"
30
31PACKAGES =+ "${PN}-script"
32
33S = "${WORKDIR}/git"
34
35inherit perlnative pkgconfig
36
37#EXTRA_OEMAKE = "-e MAKEFLAGS="
38
39do_configure:append () {
40    # Make sure we use our nativeperl wrapper
41    sed -i "1s:#!.*:#!/usr/bin/env nativeperl:" ${S}/*.pl
42    cp ${WORKDIR}/long-help ${S}
43}
44
45do_install () {
46    sed -i s:m600:m\ 600:g Makefile
47    oe_runmake 'DESTDIR=${D}' 'PREFIX=/usr' install
48    rm -f ${D}${sysconfdir}/vpnc/vpnc.conf #This file is useless
49    install ${WORKDIR}/default.conf ${D}${sysconfdir}/vpnc/default.conf
50}
51
52SYSROOT_PREPROCESS_FUNCS += "vpnc_sysroot_preprocess"
53
54vpnc_sysroot_preprocess () {
55    install -d ${SYSROOT_DESTDIR}${sysconfdir}/vpnc
56    install -m 755 ${D}${sysconfdir}/vpnc/vpnc-script ${SYSROOT_DESTDIR}${sysconfdir}/vpnc
57}
58
59FILES:${PN}-script = "${sysconfdir}/vpnc/vpnc-script"
60
61CONFFILES:${PN} = "${sysconfdir}/vpnc/default.conf"
62RDEPENDS:${PN} = "perl-module-io-file ${PN}-script"
63RRECOMMENDS:${PN} = "kernel-module-tun"
64