1SUMMARY = "NetworkManager"
2HOMEPAGE = "https://wiki.gnome.org/Projects/NetworkManager"
3SECTION = "net/misc"
4
5LICENSE = "GPL-2.0-or-later & LGPL-2.1-or-later"
6LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
7                    file://COPYING.LGPL;md5=4fbd65380cdd255951079008b364516c \
8"
9
10DEPENDS = " \
11    coreutils-native \
12    intltool-native \
13    libxslt-native \
14    libnl \
15    udev \
16    util-linux \
17    libndp \
18    libnewt \
19    curl \
20    dbus \
21"
22
23GNOMEBASEBUILDCLASS = "meson"
24inherit gnomebase gettext update-rc.d systemd gobject-introspection gtk-doc update-alternatives upstream-version-is-even
25
26SRC_URI = " \
27    ${GNOME_MIRROR}/NetworkManager/${@gnome_verdir("${PV}")}/NetworkManager-${PV}.tar.xz \
28    file://${BPN}.initd \
29    file://enable-dhcpcd.conf \
30    file://enable-iwd.conf \
31    file://0001-do-not-ask-host-for-ifcfg-defaults.patch \
32    file://0001-libnm-client-test-add-dependency-libnm_client_public.patch \
33"
34SRC_URI[sha256sum] = "ab855cbe3b41832e9a3b003810e7c7313dfe19e630d29806d14d87fdd1470cab"
35
36S = "${WORKDIR}/NetworkManager-${PV}"
37
38# ['auto', 'symlink', 'file', 'netconfig', 'resolvconf']
39NETWORKMANAGER_DNS_RC_MANAGER_DEFAULT ??= "auto"
40
41# ['dhcpcanon', 'dhclient', 'dhcpcd', 'internal', 'nettools']
42NETWORKMANAGER_DHCP_DEFAULT ??= "internal"
43
44EXTRA_OEMESON = "\
45    -Difcfg_rh=false \
46    -Dtests=yes \
47    -Dnmtui=true \
48    -Dudev_dir=${nonarch_base_libdir}/udev \
49    -Dlibpsl=false \
50    -Dqt=false \
51    -Dconfig_dns_rc_manager_default=${NETWORKMANAGER_DNS_RC_MANAGER_DEFAULT} \
52    -Dconfig_dhcp_default=${NETWORKMANAGER_DHCP_DEFAULT} \
53    -Ddhcpcanon=false \
54"
55
56# stolen from https://github.com/void-linux/void-packages/blob/master/srcpkgs/NetworkManager/template
57# avoids:
58# | ../NetworkManager-1.16.0/libnm-core/nm-json.c:106:50: error: 'RTLD_DEEPBIND' undeclared (first use in this function); did you mean 'RTLD_DEFAULT'?
59CFLAGS:append:libc-musl = " \
60    -DRTLD_DEEPBIND=0 \
61"
62
63do_compile:prepend() {
64    export GI_TYPELIB_PATH="${B}}/src/libnm-client-impl${GI_TYPELIB_PATH:+:$GI_TYPELIB_PATH}"
65}
66
67PACKAGECONFIG ??= "readline nss ifupdown dnsmasq nmcli vala \
68    ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'systemd', bb.utils.contains('DISTRO_FEATURES', 'x11', 'consolekit', '', d), d)} \
69    ${@bb.utils.contains('DISTRO_FEATURES', 'bluetooth', 'bluez5', '', d)} \
70    ${@bb.utils.filter('DISTRO_FEATURES', 'wifi polkit', d)} \
71    ${@bb.utils.contains('DISTRO_FEATURES', 'selinux', 'selinux audit', '', d)} \
72"
73
74inherit ${@bb.utils.contains('PACKAGECONFIG', 'nmcli', 'bash-completion', '', d)}
75inherit ${@bb.utils.contains('PACKAGECONFIG', 'vala', 'vala', '', d)}
76
77PACKAGECONFIG[systemd] = "\
78    -Dsystemdsystemunitdir=${systemd_unitdir}/system -Dsession_tracking=systemd,\
79    -Dsystemdsystemunitdir=no -Dsystemd_journal=false -Dsession_tracking=no\
80"
81PACKAGECONFIG[polkit] = "-Dpolkit=true,-Dpolkit=false,polkit"
82PACKAGECONFIG[bluez5] = "-Dbluez5_dun=true,-Dbluez5_dun=false,bluez5"
83# consolekit is not picked by shlibs, so add it to RDEPENDS too
84PACKAGECONFIG[consolekit] = "-Dsession_tracking_consolekit=true,-Dsession_tracking_consolekit=false,consolekit,consolekit"
85PACKAGECONFIG[modemmanager] = "-Dmodem_manager=true,-Dmodem_manager=false,modemmanager mobile-broadband-provider-info"
86PACKAGECONFIG[ppp] = "-Dppp=true -Dpppd=/usr/sbin/pppd,-Dppp=false,ppp,ppp"
87PACKAGECONFIG[dnsmasq] = "-Ddnsmasq=${bindir}/dnsmasq"
88PACKAGECONFIG[nss] = "-Dcrypto=nss,,nss"
89PACKAGECONFIG[resolvconf] = "-Dresolvconf=${base_sbindir}/resolvconf,-Dresolvconf=no,,resolvconf"
90PACKAGECONFIG[gnutls] = "-Dcrypto=gnutls,,gnutls"
91PACKAGECONFIG[wifi] = "-Dwext=true -Dwifi=true,-Dwext=false -Dwifi=false"
92PACKAGECONFIG[iwd] = "-Diwd=true,-Diwd=false"
93PACKAGECONFIG[ifupdown] = "-Difupdown=true,-Difupdown=false"
94PACKAGECONFIG[cloud-setup] = "-Dnm_cloud_setup=true,-Dnm_cloud_setup=false"
95PACKAGECONFIG[nmcli] = "-Dnmcli=true,-Dnmcli=false"
96PACKAGECONFIG[readline] = "-Dreadline=libreadline,,readline"
97PACKAGECONFIG[libedit] = "-Dreadline=libedit,,libedit"
98PACKAGECONFIG[ovs] = "-Dovs=true,-Dovs=false,jansson"
99PACKAGECONFIG[audit] = "-Dlibaudit=yes,-Dlibaudit=no"
100PACKAGECONFIG[selinux] = "-Dselinux=true,-Dselinux=false,libselinux"
101PACKAGECONFIG[vala] = "-Dvapi=true,-Dvapi=false"
102PACKAGECONFIG[dhcpcd] = "-Ddhcpcd=yes,-Ddhcpcd=no,,dhcpcd"
103PACKAGECONFIG[dhclient] = "-Ddhclient=yes,-Ddhclient=no,,dhcp"
104PACKAGECONFIG[concheck] = "-Dconcheck=true,-Dconcheck=false"
105
106
107PACKAGES =+ " \
108    ${PN}-adsl \
109    ${PN}-bluetooth \
110    ${PN}-cloud-setup \
111    ${PN}-nmcli ${PN}-nmcli-doc \
112    ${PN}-nmtui ${PN}-nmtui-doc \
113    ${PN}-wifi \
114    ${PN}-wwan \
115    ${PN}-ovs ${PN}-ovs-doc \
116    ${PN}-ppp \
117"
118
119SYSTEMD_PACKAGES = "${PN} ${PN}-cloud-setup"
120
121NETWORKMANAGER_PLUGINDIR = "${libdir}/NetworkManager/${PV}"
122
123FILES:${PN}-adsl = "${NETWORKMANAGER_PLUGINDIR}/libnm-device-plugin-adsl.so"
124
125FILES:${PN}-bluetooth = "${NETWORKMANAGER_PLUGINDIR}/libnm-device-plugin-bluetooth.so"
126
127FILES:${PN}-cloud-setup = " \
128    ${libexecdir}/nm-cloud-setup \
129    ${systemd_system_unitdir}/nm-cloud-setup.service \
130    ${systemd_system_unitdir}/nm-cloud-setup.timer \
131    ${libdir}/NetworkManager/dispatcher.d/90-nm-cloud-setup.sh \
132    ${libdir}/NetworkManager/dispatcher.d/no-wait.d/90-nm-cloud-setup.sh \
133"
134ALLOW_EMPTY:${PN}-cloud-setup = "1"
135SYSTEMD_SERVICE:${PN}-cloud-setup = "${@bb.utils.contains('PACKAGECONFIG', 'cloud-setup', 'nm-cloud-setup.service nm-cloud-setup.timer', '', d)}"
136
137FILES:${PN}-nmcli = " \
138    ${bindir}/nmcli \
139"
140
141FILES:${PN}-nmcli-doc = " \
142    ${mandir}/man1/nmcli* \
143"
144
145FILES:${PN}-nmtui = " \
146    ${bindir}/nmtui \
147    ${bindir}/nmtui-edit \
148    ${bindir}/nmtui-connect \
149    ${bindir}/nmtui-hostname \
150"
151
152FILES:${PN}-nmtui-doc = " \
153    ${mandir}/man1/nmtui* \
154"
155
156FILES:${PN}-wifi = "${NETWORKMANAGER_PLUGINDIR}/libnm-device-plugin-wifi.so"
157
158FILES:${PN}-wwan = "\
159    ${NETWORKMANAGER_PLUGINDIR}/libnm-device-plugin-wwan.so \
160    ${NETWORKMANAGER_PLUGINDIR}/libnm-wwan.so \
161"
162
163FILES:${PN}-ovs = "\
164    ${NETWORKMANAGER_PLUGINDIR}/libnm-device-plugin-ovs.so \
165    ${systemd_system_unitdir}/NetworkManager.service.d/NetworkManager-ovs.conf \
166"
167
168FILES:${PN}-ovs-doc = "\
169    ${mandir}/man7/nm-openvswitch.7* \
170"
171
172FILES:${PN}-ppp = "\
173    ${NETWORKMANAGER_PLUGINDIR}/libnm-ppp-plugin.so \
174    ${libdir}/pppd/*/nm-pppd-plugin.so \
175"
176
177FILES:${PN}-dev += " \
178    ${libdir}/pppd/*/*.la \
179    ${libdir}/NetworkManager/*.la \
180    ${NETWORKMANAGER_PLUGINDIR}/*.la \
181"
182
183FILES:${PN} += " \
184    ${libexecdir} \
185    ${libdir}/NetworkManager \
186    ${nonarch_libdir}/firewalld/zones \
187    ${nonarch_libdir}/NetworkManager/conf.d \
188    ${nonarch_libdir}/NetworkManager/dispatcher.d \
189    ${nonarch_libdir}/NetworkManager/dispatcher.d/pre-down.d \
190    ${nonarch_libdir}/NetworkManager/dispatcher.d/pre-up.d \
191    ${nonarch_libdir}/NetworkManager/dispatcher.d/no-wait.d \
192    ${nonarch_libdir}/NetworkManager/VPN \
193    ${nonarch_libdir}/NetworkManager/system-connections \
194    ${datadir}/polkit-1 \
195    ${datadir}/dbus-1 \
196    ${nonarch_base_libdir}/udev/* \
197    ${systemd_system_unitdir} \
198"
199
200RRECOMMENDS:${PN} += "\
201    iptables \
202    ${@bb.utils.filter('PACKAGECONFIG', 'dnsmasq', d)} \
203    ${@bb.utils.contains('PACKAGECONFIG','adsl','${PN}-adsl','',d)} \
204    ${@bb.utils.contains('PACKAGECONFIG','bluez5','${PN}-bluetooth','',d)} \
205    ${@bb.utils.contains('PACKAGECONFIG','cloud-setup','${PN}-cloud-setup','',d)} \
206    ${@bb.utils.contains('PACKAGECONFIG','nmcli','${PN}-nmcli','',d)} \
207    ${@bb.utils.contains('PACKAGECONFIG','nmtui','${PN}-nmtui','',d)} \
208    ${@bb.utils.contains('PACKAGECONFIG','wifi','${PN}-wifi','',d)} \
209    ${@bb.utils.contains('PACKAGECONFIG','wwan','${PN}-wwan','',d)} \
210    ${@bb.utils.contains('PACKAGECONFIG','ovs','${PN}-ovs','',d)} \
211    ${@bb.utils.contains('PACKAGECONFIG','ppp','${PN}-ppp','',d)} \
212"
213RCONFLICTS:${PN} = "connman"
214
215
216INITSCRIPT_NAME = "network-manager"
217SYSTEMD_SERVICE:${PN} = "\
218    NetworkManager.service \
219    NetworkManager-dispatcher.service \
220"
221
222ALTERNATIVE_PRIORITY = "100"
223ALTERNATIVE:${PN} = "${@bb.utils.contains('DISTRO_FEATURES','systemd','resolv-conf','',d)}"
224ALTERNATIVE_TARGET[resolv-conf] = "${@bb.utils.contains('DISTRO_FEATURES','systemd','${sysconfdir}/resolv-conf.NetworkManager','',d)}"
225ALTERNATIVE_LINK_NAME[resolv-conf] = "${@bb.utils.contains('DISTRO_FEATURES','systemd','${sysconfdir}/resolv.conf','',d)}"
226
227do_install:append() {
228    install -Dm 0755 ${WORKDIR}/${BPN}.initd ${D}${sysconfdir}/init.d/network-manager
229
230    rm -rf ${D}/run ${D}${localstatedir}/run
231
232    if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then
233        # For read-only filesystem, do not create links during bootup
234        ln -sf ../run/NetworkManager/resolv.conf ${D}${sysconfdir}/resolv-conf.NetworkManager
235
236        # systemd v210 and newer do not need this rule file
237        rm ${D}/${nonarch_base_libdir}/udev/rules.d/84-nm-drivers.rules
238    fi
239
240    # Enable iwd if compiled
241    if ${@bb.utils.contains('PACKAGECONFIG','iwd','true','false',d)}; then
242        install -Dm 0644 ${WORKDIR}/enable-iwd.conf ${D}${libdir}/NetworkManager/conf.d/enable-iwd.conf
243    fi
244
245    # Enable dhcpd if compiled
246    if ${@bb.utils.contains('PACKAGECONFIG','dhcpcd','true','false',d)}; then
247        install -Dm 0644 ${WORKDIR}/enable-dhcpcd.conf ${D}${libdir}/NetworkManager/conf.d/enable-dhcpcd.conf
248    fi
249}
250