1SUMMARY = "NetworkManager-openvpn-plugin"
2SECTION = "net/misc"
3
4LICENSE = "GPL-2.0-or-later"
5LIC_FILES_CHKSUM = "file://COPYING;md5=100d5a599bead70ddcd70dcd73f2e29c"
6
7DEPENDS = "dbus dbus-glib networkmanager openvpn intltool-native glib-2.0-native"
8
9inherit gnomebase useradd gettext systemd
10
11SRC_URI = "${GNOME_MIRROR}/NetworkManager-openvpn/${@gnome_verdir("${PV}")}/NetworkManager-openvpn-${PV}.tar.xz"
12
13SRC_URI[sha256sum] = "53dfb0acf64478adc728074f162f62e60bff62a605bd897eb88b267e7057927a"
14
15S = "${WORKDIR}/NetworkManager-openvpn-${PV}"
16
17# meta-gnome in layers is required using gnome:
18PACKAGECONFIG[gnome] = "--with-gnome,--without-gnome,gtk+3 libnma libsecret"
19
20do_configure:append() {
21    # network-manager-openvpn.metainfo.xml is created in source folder but
22    # compile expects it in build folder. As long as nobody comes up with a
23    # better solution just support build:
24    if [ -e ${S}/appdata/network-manager-openvpn.metainfo.xml ]; then
25        mkdir -p ${B}/appdata
26        cp -f ${S}/appdata/network-manager-openvpn.metainfo.xml ${B}/appdata/
27    fi
28}
29
30do_install:append () {
31    rm -rf ${D}${libdir}/NetworkManager/*.la
32}
33
34# Create user and group nm-openvpn that are needed since version 1.0.6
35USERADD_PACKAGES = "${PN}"
36USERADD_PARAM:${PN} = "--system nm-openvpn"
37
38FILES:${PN} += " \
39    ${datadir}/dbus-1 \
40    ${datadir}/metainfo \
41    ${libdir}/NetworkManager/*.so \
42    ${nonarch_libdir}/NetworkManager/VPN/nm-openvpn-service.name \
43"
44
45FILES:${PN}-staticdev += " \
46    ${libdir}/NetworkManager/*.a \
47"
48
49RDEPENDS:${PN} = " \
50    networkmanager \
51    openvpn \
52"
53