1SUMMARY = "Lightweight UPnP IGD daemon"
2DESCRIPTION = "The miniUPnP daemon is an UPnP IGD (internet gateway device) \
3which provide NAT traversal services to any UPnP enabled client on \
4the network."
5
6SECTION = "networking"
7LICENSE = "BSD-3-Clause"
8LIC_FILES_CHKSUM = "file://LICENSE;md5=a1ed15843ce66639bcf9f109cf247870"
9
10inherit autotools gettext pkgconfig systemd
11
12DEPENDS += "iptables net-tools util-linux libmnl libnetfilter-conntrack"
13
14SRC_URI = "http://miniupnp.tuxfamily.org/files/download.php?file=${BP}.tar.gz;downloadfilename=${BP}.tar.gz \
15           file://miniupnpd.service \
16           file://0001-Add-OpenEmbedded-cross-compile-case.patch \
17           "
18SRC_URI[md5sum] = "340789edd49c113afe37834cc901a1e8"
19SRC_URI[sha256sum] = "218fad7af31f3c22fb4c9db28a55a2a8b5067d41f5b38f52008a057a00d2206d"
20
21IPV6 = "${@bb.utils.contains('DISTRO_FEATURES', 'ipv6', '--ipv6', '', d)}"
22
23do_configure:prepend() {
24   echo "${@d.getVar('DISTRO_VERSION')}" > ${S}/os.openembedded
25}
26
27do_compile() {
28    cd ${S}
29    CONFIG_OPTIONS="${IPV6} --leasefile --vendorcfg" oe_runmake -f Makefile.linux config.h
30    CONFIG_OPTIONS="${IPV6} --leasefile --vendorcfg" oe_runmake -f Makefile.linux
31}
32
33do_install() {
34    install -d ${D}/${sbindir}
35    install ${S}/miniupnpd ${D}/${sbindir}
36    install -d ${D}/${sysconfdir}/${BPN}
37    install ${S}/netfilter/iptables_init.sh ${D}/${sysconfdir}/${BPN}
38    install ${S}/netfilter/iptables_removeall.sh ${D}/${sysconfdir}/${BPN}
39    install ${S}/netfilter/ip6tables_init.sh ${D}/${sysconfdir}/${BPN}
40    install ${S}/netfilter/miniupnpd_functions.sh ${D}/${sysconfdir}/${BPN}
41    install ${S}/netfilter/ip6tables_removeall.sh ${D}/${sysconfdir}/${BPN}
42    install -m 0644 -b ${S}/miniupnpd.conf ${D}/${sysconfdir}/${BPN}
43    install -d ${D}/${sysconfdir}/init.d
44    install ${S}/linux/miniupnpd.init.d.script ${D}/${sysconfdir}/init.d/miniupnpd
45
46    install -d ${D}${systemd_unitdir}/system
47    install -m 0644 ${WORKDIR}/miniupnpd.service ${D}${systemd_unitdir}/system/
48}
49
50SYSTEMD_SERVICE:${PN} = "miniupnpd.service"
51