1SUMMARY = "Civetweb embedded web server"
2HOMEPAGE = "https://github.com/civetweb/civetweb"
3
4LICENSE = "MIT"
5LIC_FILES_CHKSUM = "file://LICENSE.md;md5=50bd1d7f135b50d7e218996ba28d0d88"
6
7SRCREV = "4b440a339979852d5a51fb11a822952712231c23"
8PV = "1.12+git${SRCPV}"
9SRC_URI = "git://github.com/civetweb/civetweb.git;branch=master;protocol=https \
10           file://0001-Unittest-Link-librt-and-libm-using-l-option.patch \
11           "
12
13S = "${WORKDIR}/git"
14
15# civetweb supports building with make or cmake (although cmake lacks few features)
16inherit cmake
17
18# Disable Lua and Duktape because they do not compile from CMake (as of v1.8, v1.9 and v1.10).
19# Disable ASAN as it is included only in Debug build.
20EXTRA_OECMAKE = " \
21    -DBUILD_SHARED_LIBS=ON \
22    -DCIVETWEB_ENABLE_DUKTAPE=OFF \
23    -DCIVETWEB_ENABLE_LUA=OFF \
24    -DCIVETWEB_ENABLE_ASAN=OFF \
25    -DCIVETWEB_BUILD_TESTING=OFF \
26"
27
28# Building with ninja fails on missing third_party/lib/libcheck.a (which
29# should come from external CMake project)
30OECMAKE_GENERATOR = "Unix Makefiles"
31
32PACKAGECONFIG ??= "caching ipv6 server ssl websockets"
33PACKAGECONFIG[caching] = "-DCIVETWEB_DISABLE_CACHING=OFF,-DCIVETWEB_DISABLE_CACHING=ON,"
34PACKAGECONFIG[cgi] = "-DCIVETWEB_DISABLE_CGI=OFF,-DCIVETWEB_DISABLE_CGI=ON,"
35PACKAGECONFIG[cpp] = "-DCIVETWEB_ENABLE_CXX=ON,-DCIVETWEB_ENABLE_CXX=OFF,"
36PACKAGECONFIG[debug] = "-DCIVETWEB_ENABLE_MEMORY_DEBUGGING=ON,-DCIVETWEB_ENABLE_MEMORY_DEBUGGING=OFF,"
37PACKAGECONFIG[ipv6] = "-DCIVETWEB_ENABLE_IPV6=ON,-DCIVETWEB_ENABLE_IPV6=OFF,"
38PACKAGECONFIG[server] = "-DCIVETWEB_ENABLE_SERVER_EXECUTABLE=ON -DCIVETWEB_INSTALL_EXECUTABLE=ON,-DCIVETWEB_ENABLE_SERVER_EXECUTABLE=OFF -DCIVETWEB_INSTALL_EXECUTABLE=OFF,"
39PACKAGECONFIG[ssl] = "-DCIVETWEB_ENABLE_SSL=ON -DCIVETWEB_SSL_OPENSSL_API_1_1=OFF -DCIVETWEB_ENABLE_SSL_DYNAMIC_LOADING=OFF,-DCIVETWEB_ENABLE_SSL=OFF,openssl (=1.0.2%),"
40PACKAGECONFIG[websockets] = "-DCIVETWEB_ENABLE_WEBSOCKETS=ON,-DCIVETWEB_ENABLE_WEBSOCKETS=OFF,"
41
42BBCLASSEXTEND = "native"
43