1SUMMARY = "BearSSL is an implementation of the SSL/TLS protocol (RFC 5246) written in C"
2DESCRIPTION = "BearSSL is an implementation of the SSL/TLS protocol (RFC \
35246) written in C. It aims at offering the following features: \
4  * Be correct and secure. In particular, insecure protocol versions and \
5    choices of algorithms are not supported, by design; cryptographic \
6    algorithm implementations are constant-time by default. \
7  * Be small, both in RAM and code footprint. For instance, a minimal \
8    server implementation may fit in about 20 kilobytes of compiled code \
9    and 25 kilobytes of RAM. \
10  * Be highly portable. BearSSL targets not only “big” operating systems \
11    like Linux and Windows, but also small embedded systems and even special \
12    contexts like bootstrap code. \
13  * Be feature-rich and extensible. SSL/TLS has many defined cipher suites \
14    and extensions; BearSSL should implement most of them, and allow extra \
15    algorithm implementations to be added afterwards, possibly from third \
16    parties."
17HOMEPAGE = "https://bearssl.org"
18
19SECTION = "libs"
20
21inherit lib_package
22
23LICENSE = "MIT"
24LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=1fc37e1037ae673975fbcb96a98f7191"
25
26PV .= "+git${SRCPV}"
27SRCREV = "79b1a9996c094ff593ae50bc4edc1f349f39dd6d"
28SRC_URI = "git://www.bearssl.org/git/BearSSL;protocol=https;branch=master \
29	   file://0001-conf-Unix.mk-remove-fixed-command-definitions.patch \
30	   file://0002-test-test_x509.c-fix-potential-overflow-issue.patch \
31           file://0001-make-Pass-LDFLAGS-when-building-shared-objects.patch \
32	   "
33
34# without compile errors like
35# <..>/ld: build/obj/ghash_pclmul.o: warning: relocation against `br_ghash_pclmul' in read-only section `.text'
36CFLAGS += "-fPIC"
37
38S = "${WORKDIR}/git"
39B = "${S}"
40
41do_install() {
42    mkdir -p ${D}/${bindir} ${D}/${libdir}
43    install -m 0644 ${B}/build/brssl ${D}/${bindir}
44    install -m 0644 ${B}/build/libbearssl.so ${D}/${libdir}/libbearssl.so.6.0.0
45    ln -s libbearssl.so.6.0.0 ${D}/${libdir}/libbearssl.so.6
46    ln -s libbearssl.so.6.0.0 ${D}/${libdir}/libbearssl.so
47}
48