1SUMMARY = "Linux libcamera framework"
2SECTION = "libs"
3
4LICENSE = "GPL-2.0-or-later & LGPL-2.1-or-later"
5
6LIC_FILES_CHKSUM = "\
7    file://LICENSES/GPL-2.0-or-later.txt;md5=fed54355545ffd980b814dab4a3b312c \
8    file://LICENSES/LGPL-2.1-or-later.txt;md5=2a4f4fd2128ea2f65047ee63fbca9f68 \
9"
10
11SRC_URI = " \
12        git://git.libcamera.org/libcamera/libcamera.git;protocol=https;branch=master \
13"
14
15SRCREV = "acf8d028edda0a59b10e15962c2606137a4940af"
16
17PV = "202105+git${SRCPV}"
18
19S = "${WORKDIR}/git"
20
21DEPENDS = "python3-pyyaml-native python3-jinja2-native python3-ply-native python3-jinja2-native udev gnutls boost chrpath-native libevent"
22DEPENDS += "${@bb.utils.contains('DISTRO_FEATURES', 'qt', 'qtbase qtbase-native', '', d)}"
23
24PACKAGES =+ "${PN}-gst"
25
26PACKAGECONFIG ??= ""
27PACKAGECONFIG[gst] = "-Dgstreamer=enabled,-Dgstreamer=disabled,gstreamer1.0 gstreamer1.0-plugins-base"
28
29EXTRA_OEMESON = " \
30    -Dpipelines=uvcvideo,simple,vimc \
31    -Dipas=vimc \
32    -Dv4l2=true \
33    -Dcam=enabled \
34    -Dlc-compliance=disabled \
35    -Dtest=false \
36    -Ddocumentation=disabled \
37"
38
39RDEPENDS:${PN} = "${@bb.utils.contains('DISTRO_FEATURES', 'wayland qt', 'qtwayland', '', d)}"
40
41inherit meson pkgconfig python3native
42
43do_configure:prepend() {
44    sed -i -e 's|py_compile=True,||' ${S}/utils/ipc/mojo/public/tools/mojom/mojom/generate/template_expander.py
45}
46
47do_install:append() {
48    chrpath -d ${D}${libdir}/libcamera.so.0.0.0
49    chrpath -d ${D}${libdir}/libcamera-base.so.0.0.0
50}
51
52addtask do_recalculate_ipa_signatures_package after do_package before do_packagedata
53do_recalculate_ipa_signatures_package() {
54    local modules
55    for module in $(find ${PKGD}/usr/lib/libcamera -name "*.so.sign"); do
56        module="${module%.sign}"
57        if [ -f "${module}" ] ; then
58            modules="${modules} ${module}"
59        fi
60    done
61
62    ${S}/src/ipa/ipa-sign-install.sh ${B}/src/ipa-priv-key.pem "${modules}"
63}
64
65FILES:${PN}-dev = "${includedir} ${libdir}/pkgconfig"
66FILES:${PN}-dev += " ${libdir}/libcamera.so"
67FILES:${PN} += " ${libdir}/libcamera.so.0"
68FILES:${PN} += " ${libdir}/libcamera.so.0.0.0"
69FILES:${PN}-dev += " ${libdir}/libcamera-base.so"
70FILES:${PN} += " ${libdir}/libcamera-base.so.0"
71FILES:${PN} += " ${libdir}/libcamera-base.so.0.0.0"
72FILES:${PN} += " ${libdir}/v4l2-compat.so"
73FILES:${PN}-gst = "${libdir}/gstreamer-1.0/libgstlibcamera.so"
74FILES:${PN} += " ${bindir}/cam"
75