1SUMMARY = "XFS Filesystem Utilities"
2HOMEPAGE = "http://oss.sgi.com/projects/xfs"
3SECTION = "base"
4LICENSE = "GPL-2.0-only & LGPL-2.1-only"
5LICENSE:libhandle = "LGPL-2.1-only"
6LIC_FILES_CHKSUM = "file://LICENSES/GPL-2.0;md5=e6a75371ba4d16749254a51215d13f97 \
7                    file://LICENSES/LGPL-2.1;md5=b370887980db5dd40659b50909238dbd"
8DEPENDS = "util-linux util-linux-native"
9SRC_URI = "https://www.kernel.org/pub/linux/utils/fs/xfs/xfsprogs/${BP}.tar.xz \
10           file://remove_flags_from_build_flags.patch \
11           file://0001-Check-for-MAP_SYNC-in-sys-mman.h.patch \
12           file://0002-include-include-xfs-linux.h-after-sys-mman.h.patch \
13           file://0001-support-usrmerge.patch \
14           "
15SRC_URI[sha256sum] = "4e142d4babe086adf9016d8c606c805829da08e46389a4433f40346204f90cdb"
16inherit autotools-brokensep pkgconfig
17
18PACKAGES =+ "${PN}-fsck ${PN}-mkfs ${PN}-repair libhandle"
19
20DEPENDS += "util-linux libinih"
21
22RDEPENDS:${PN} = "${PN}-fsck ${PN}-mkfs ${PN}-repair"
23
24FILES:${PN}-fsck = "${base_sbindir}/fsck.xfs"
25FILES:${PN}-mkfs = "${base_sbindir}/mkfs.xfs"
26FILES:${PN}-repair = "${base_sbindir}/xfs_repair"
27
28FILES:libhandle = "${base_libdir}/libhandle${SOLIBS}"
29
30EXTRA_OECONF = "--enable-gettext=no \
31                --enable-scrub=no \
32                INSTALL_USER=root \
33                INSTALL_GROUP=root \
34                ac_cv_header_aio_h=yes \
35                ac_cv_lib_rt_lio_listio=yes \
36                OPTIMIZER='${SELECTED_OPTIMIZATION}' \
37"
38
39DISABLE_STATIC = ""
40EXTRA_AUTORECONF += "-I ${S}/m4 --exclude=autoheader"
41
42PACKAGECONFIG ??= "blkid"
43
44PACKAGECONFIG[blkid] = "--enable-blkid=yes,--enable-blkid=no,util-linux"
45
46export DEBUG="-DNDEBUG"
47export BUILD_VERBOSE="1"
48export tagname="CC"
49
50EXTRA_OEMAKE = "DIST_ROOT='${D}'"
51
52do_configure () {
53    export BUILD_CC="${BUILD_CC} ${BUILD_CFLAGS}"
54    # Prevent Makefile from calling configure without arguments,
55    # when do_configure gets called for a second time.
56    rm -f ${B}/include/builddefs ${B}/include/platform_defs.h ${B}/configure
57    # Recreate configure script.
58    oe_runmake configure
59    install -m 0755 ${STAGING_DATADIR_NATIVE}/gnu-config/config.guess ${S}
60    install -m 0755 ${STAGING_DATADIR_NATIVE}/gnu-config/config.sub ${S}
61    oe_runconf
62}
63
64do_install:append() {
65        oe_runmake 'DESTDIR=${D}' install-dev
66        rm ${D}${libdir}/*.la
67        rmdir --ignore-fail-on-non-empty ${D}${libdir}
68
69        if [ ${libdir} != ${base_libdir} ];then
70            ln -sf -r ${D}${libdir}/libhandle.a ${D}${base_libdir}/libhandle.a
71            ln -sf -r ${D}${base_libdir}/libhandle.so ${D}${libdir}/libhandle.so
72        fi
73}
74