1DESCRIPTION = "The NTFS-3G driver is an open source, freely available NTFS driver for Linux with read and write support."
2HOMEPAGE = "http://www.ntfs-3g.org/"
3DEPENDS = "fuse libgcrypt"
4PROVIDES = "ntfsprogs ntfs-3g"
5LICENSE = "GPL-2.0-only & LGPL-2.0-only"
6LIC_FILES_CHKSUM = "file://COPYING;md5=59530bdf33659b29e73d4adb9f9f6552 \
7                    file://COPYING.LIB;md5=f30a9716ef3762e3467a2f62bf790f0a"
8
9SRC_URI = "http://tuxera.com/opensource/ntfs-3g_ntfsprogs-${PV}.tgz \
10           file://0001-libntfs-3g-Makefile.am-fix-install-failed-while-host.patch \
11"
12S = "${WORKDIR}/ntfs-3g_ntfsprogs-${PV}"
13SRC_URI[sha256sum] = "0489fbb6972581e1b417ab578d543f6ae522e7fa648c3c9b49c789510fd5eb93"
14
15UPSTREAM_CHECK_URI = "https://www.tuxera.com/community/open-source-ntfs-3g/"
16UPSTREAM_CHECK_REGEX = "ntfs-3g_ntfsprogs-(?P<pver>\d+(\.\d+)+)\.tgz"
17
18inherit autotools pkgconfig
19
20PACKAGECONFIG ??= ""
21PACKAGECONFIG[uuid] = "--with-uuid,--without-uuid,util-linux"
22
23# required or it calls ldconfig at install step
24EXTRA_OEMAKE = "LDCONFIG=echo"
25
26PACKAGES =+ "ntfs-3g ntfsprogs libntfs-3g"
27
28FILES:ntfs-3g = "${base_sbindir}/*.ntfs-3g ${bindir}/ntfs-3g* ${base_sbindir}/mount.ntfs"
29RDEPENDS:ntfs-3g += "fuse"
30RRECOMMENDS:ntfs-3g = "util-linux-mount"
31
32FILES:ntfsprogs = "${base_sbindir}/* ${bindir}/* ${sbindir}/*"
33FILES:libntfs-3g = "${libdir}/*${SOLIBS}"
34
35do_install:append() {
36    # Standard mount will execute the program /sbin/mount.TYPE when called.
37    # Add a symbolic link to let mount find ntfs.
38    ln -sf mount.ntfs-3g ${D}${base_sbindir}/mount.ntfs
39    rmdir ${D}${libdir}/ntfs-3g
40
41    # Handle when usrmerge is in effect. Some files are installed to /sbin
42    # regardless of the value of ${base_sbindir}.
43    if [ "${base_sbindir}" != /sbin ] && [ -d ${D}/sbin ]; then
44        mkdir -p ${D}${base_sbindir}
45        mv ${D}/sbin/* ${D}${base_sbindir}
46        rmdir ${D}/sbin
47    fi
48}
49
50# Satisfy the -dev runtime dependency
51ALLOW_EMPTY:${PN} = "1"
52
53CVE_PRODUCT = "tuxera:ntfs-3g"
54