xref: /OK3568_Linux_fs/u-boot/board/freescale/mx31ads/u-boot.lds (revision 4882a59341e53eb6f0b4789bf948001014eff981) 
1/*
2 * January 2004 - Changed to support H4 device
3 * Copyright (c) 2004 Texas Instruments
4 *
5 * (C) Copyright 2002
6 * Gary Jennejohn, DENX Software Engineering, <garyj@denx.de>
7 *
8 * SPDX-License-Identifier:	GPL-2.0+
9 */
10
11OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
12OUTPUT_ARCH(arm)
13ENTRY(_start)
14SECTIONS
15{
16	. = 0x00000000;
17
18	. = ALIGN(4);
19	.text	   :
20	{
21		*(.__image_copy_start)
22	  /* WARNING - the following is hand-optimized to fit within	*/
23	  /* the sector layout of our flash chips!	XXX FIXME XXX	*/
24
25	  *					(.vectors)
26	  arch/arm/cpu/arm1136/start.o		(.text*)
27	  board/freescale/mx31ads/built-in.o	(.text*)
28	  arch/arm/lib/built-in.o		(.text*)
29	  net/built-in.o			(.text*)
30	  drivers/mtd/built-in.o		(.text*)
31
32	  . = DEFINED(env_offset) ? env_offset : .;
33	  env/embedded.o(.text*)
34
35	  *(.text*)
36	}
37	. = ALIGN(4);
38	.rodata : { *(.rodata*) }
39
40	. = ALIGN(4);
41	.data : {
42		*(.data*)
43	}
44
45	. = ALIGN(4);
46
47	. = ALIGN(4);
48	.u_boot_list : {
49		KEEP(*(SORT(.u_boot_list*)));
50	}
51
52	. = ALIGN(4);
53
54	.image_copy_end :
55	{
56		*(.__image_copy_end)
57	}
58
59	.rel_dyn_start :
60	{
61		*(.__rel_dyn_start)
62	}
63
64	.rel.dyn : {
65		*(.rel*)
66	}
67
68	.rel_dyn_end :
69	{
70		*(.__rel_dyn_end)
71	}
72
73	.hash : { *(.hash*) }
74
75	.end :
76	{
77		*(.__end)
78	}
79
80	_image_binary_end = .;
81
82/*
83 * Compiler-generated __bss_start and __bss_end, see arch/arm/lib/bss.c
84 * __bss_base and __bss_limit are for linker only (overlay ordering)
85 */
86
87	.bss_start __rel_dyn_start (OVERLAY) : {
88		KEEP(*(.__bss_start));
89		__bss_base = .;
90	}
91
92	.bss __bss_base (OVERLAY) : {
93		*(.bss*)
94		 . = ALIGN(4);
95		 __bss_limit = .;
96	}
97	.bss_end __bss_limit (OVERLAY) : {
98		KEEP(*(.__bss_end));
99	}
100
101	.dynsym _image_binary_end : { *(.dynsym) }
102	.dynbss : { *(.dynbss) }
103	.dynstr : { *(.dynstr*) }
104	.dynamic : { *(.dynamic*) }
105	.gnu.hash : { *(.gnu.hash) }
106	.plt : { *(.plt*) }
107	.interp : { *(.interp*) }
108	.gnu : { *(.gnu*) }
109	.ARM.exidx : { *(.ARM.exidx*) }
110}
111