1TARGET = QtLocation
2QT = core-private positioning-private positioningquick-private
3android {
4    # adding qtconcurrent dependency here for the osm plugin
5    QT += concurrent
6}
7
8CONFIG += simd optimize_full
9QT_FOR_CONFIG += location-private
10
11# 3rdparty headers produce warnings with MSVC
12msvc: CONFIG -= warning_clean
13
14INCLUDEPATH += ../3rdparty/earcut
15INCLUDEPATH += ../3rdparty/poly2tri
16INCLUDEPATH += ../3rdparty/clipper
17INCLUDEPATH += ../3rdparty/clip2tri
18INCLUDEPATH += ../positioning
19INCLUDEPATH += ../imports/positioning
20INCLUDEPATH *= $$PWD
21
22MODULE_PLUGIN_TYPES = \
23    geoservices
24
25QMAKE_DOCS = $$PWD/doc/qtlocation.qdocconf
26OTHER_FILES += configure.json doc/src/*.qdoc doc/src/plugins/*.qdoc  # show .qdoc files in Qt Creator
27
28PUBLIC_HEADERS += \
29                    qlocation.h \
30                    qlocationglobal.h
31
32PRIVATE_HEADERS += \
33                    qlocationglobal_p.h
34
35SOURCES += \
36           qlocation.cpp
37
38include(maps/maps.pri)
39include(places/places.pri)
40include(declarativemaps/declarativemaps.pri)
41include(declarativeplaces/declarativeplaces.pri)
42qtConfig(location-labs-plugin) {
43   include(labs/labs.pri)
44} else {
45  # FIXME: this should be moved out of plugin source code, geojson is referenced from other places
46  # within codebase,however compilation of location-labs-plugin is optional
47  PRIVATE_HEADERS += labs/qgeojson_p.h
48  SOURCES += labs/qgeojson.cpp
49}
50
51HEADERS += $$PUBLIC_HEADERS $$PRIVATE_HEADERS
52
53load(qt_module)
54
55LIBS_PRIVATE += -L$$MODULE_BASE_OUTDIR/lib -lqt_clip2tri$$qtPlatformTargetSuffix()
56