1/****************************************************************************
2**
3** Copyright (C) 2017 The Qt Company Ltd.
4** Contact: https://www.qt.io/licensing/
5**
6** This file is part of the examples of the Qt Toolkit.
7**
8** $QT_BEGIN_LICENSE:BSD$
9** Commercial License Usage
10** Licensees holding valid commercial Qt licenses may use this file in
11** accordance with the commercial license agreement provided with the
12** Software or, alternatively, in accordance with the terms contained in
13** a written agreement between you and The Qt Company. For licensing terms
14** and conditions see https://www.qt.io/terms-conditions. For further
15** information use the contact form at https://www.qt.io/contact-us.
16**
17** BSD License Usage
18** Alternatively, you may use this file under the terms of the BSD license
19** as follows:
20**
21** "Redistribution and use in source and binary forms, with or without
22** modification, are permitted provided that the following conditions are
23** met:
24**   * Redistributions of source code must retain the above copyright
25**     notice, this list of conditions and the following disclaimer.
26**   * Redistributions in binary form must reproduce the above copyright
27**     notice, this list of conditions and the following disclaimer in
28**     the documentation and/or other materials provided with the
29**     distribution.
30**   * Neither the name of The Qt Company Ltd nor the names of its
31**     contributors may be used to endorse or promote products derived
32**     from this software without specific prior written permission.
33**
34**
35** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
36** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
37** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
38** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
39** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
40** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
41** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
42** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
43** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
44** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
45** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
46**
47** $QT_END_LICENSE$
48**
49****************************************************************************/
50
51import QtQuick 2.5
52import QtLocation 5.6
53import QtQuick.Controls 1.4
54
55Item {
56    id: root
57    property Place place
58    width: parent.width
59    height: parent.height
60
61    GridView {
62        id: gridView
63
64        anchors.fill: parent
65
66        model: place.imageModel
67
68        cellWidth: width / 3
69        cellHeight: cellWidth
70
71        delegate: Rectangle {
72            width: gridView.cellWidth
73            height: gridView.cellHeight
74
75            color: "#30FFFFFF"
76
77            Image {
78                anchors.fill: parent
79                anchors.margins: 5
80
81                source: url
82
83                fillMode: Image.PreserveAspectFit
84            }
85
86            MouseArea {
87                anchors.fill: parent
88                onClicked: {
89                    listView.positionViewAtIndex(index, ListView.Contain);
90                    root.state = "list";
91                }
92            }
93        }
94    }
95
96    ListView {
97        id: listView
98
99        anchors.top: parent.top
100        anchors.bottom: position.top
101        width: parent.width
102        spacing: 10
103
104        model: place.imageModel
105        orientation: ListView.Horizontal
106        snapMode: ListView.SnapOneItem
107
108        visible: false
109
110        delegate: Item {
111            width: listView.width
112            height: listView.height
113
114            Image {
115                anchors.fill: parent
116                source: url
117                fillMode: Image.PreserveAspectFit
118
119                MouseArea {
120                    anchors.fill: parent
121                    onClicked: root.state = ""
122                }
123            }
124
125            Button {
126                id: button
127                text: qsTr("Open url")
128                anchors.bottom: parent.bottom
129                anchors.horizontalCenter: parent.horizontalCenter
130                onClicked: {
131                    Qt.openUrlExternally(supplier.url)
132                }
133            }
134        }
135    }
136
137    Label {
138        id: position
139
140        width: parent.width
141        anchors.bottom: parent.bottom
142        visible: listView.visible
143
144        text: (listView.currentIndex + 1) + '/' + listView.model.totalCount
145        horizontalAlignment: Text.AlignRight
146    }
147
148    states: [
149        State {
150            name: "list"
151            PropertyChanges {
152                target: gridView
153                visible: false
154            }
155            PropertyChanges {
156                target: listView
157                visible: true
158            }
159        }
160    ]
161}
162