1/****************************************************************************
2**
3** Copyright (C) 2017 The Qt Company Ltd.
4** Contact: https://www.qt.io/licensing/
5**
6** This file is part of the examples of the Qt Toolkit.
7**
8** $QT_BEGIN_LICENSE:BSD$
9** Commercial License Usage
10** Licensees holding valid commercial Qt licenses may use this file in
11** accordance with the commercial license agreement provided with the
12** Software or, alternatively, in accordance with the terms contained in
13** a written agreement between you and The Qt Company. For licensing terms
14** and conditions see https://www.qt.io/terms-conditions. For further
15** information use the contact form at https://www.qt.io/contact-us.
16**
17** BSD License Usage
18** Alternatively, you may use this file under the terms of the BSD license
19** as follows:
20**
21** "Redistribution and use in source and binary forms, with or without
22** modification, are permitted provided that the following conditions are
23** met:
24**   * Redistributions of source code must retain the above copyright
25**     notice, this list of conditions and the following disclaimer.
26**   * Redistributions in binary form must reproduce the above copyright
27**     notice, this list of conditions and the following disclaimer in
28**     the documentation and/or other materials provided with the
29**     distribution.
30**   * Neither the name of The Qt Company Ltd nor the names of its
31**     contributors may be used to endorse or promote products derived
32**     from this software without specific prior written permission.
33**
34**
35** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
36** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
37** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
38** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
39** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
40** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
41** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
42** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
43** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
44** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
45** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
46**
47** $QT_END_LICENSE$
48**
49****************************************************************************/
50
51import QtQuick 2.5
52import QtQuick.Controls 1.4
53import QtLocation 5.6
54
55MenuBar {
56    property variant  providerMenu: providerMenu
57    property variant  mapTypeMenu: mapTypeMenu
58    property variant  toolsMenu: toolsMenu
59    property alias isFollowMe: toolsMenu.isFollowMe
60    property alias isMiniMap: toolsMenu.isMiniMap
61
62    signal selectProvider(string providerName)
63    signal selectMapType(variant mapType)
64    signal selectTool(string tool);
65    signal toggleMapState(string state)
66
67    Menu {
68        id: providerMenu
69        title: qsTr("Provider")
70
71        function createMenu(plugins)
72        {
73            clear()
74            for (var i = 0; i < plugins.length; i++) {
75                createProviderMenuItem(plugins[i]);
76            }
77        }
78
79        function createProviderMenuItem(provider)
80        {
81            var item = addItem(provider);
82            item.checkable = true;
83            item.triggered.connect(function(){selectProvider(provider)})
84        }
85    }
86
87    Menu {
88        id: mapTypeMenu
89        title: qsTr("MapType")
90
91        function createMenu(map)
92        {
93            clear()
94            for (var i = 0; i<map.supportedMapTypes.length; i++) {
95                createMapTypeMenuItem(map.supportedMapTypes[i]).checked =
96                        (map.activeMapType === map.supportedMapTypes[i]);
97            }
98        }
99
100        function createMapTypeMenuItem(mapType)
101        {
102            var item = addItem(mapType.name);
103            item.checkable = true;
104            item.triggered.connect(function(){selectMapType(mapType)})
105            return item;
106        }
107    }
108
109    Menu {
110        id: toolsMenu
111        property bool isFollowMe: false;
112        property bool isMiniMap: false;
113        title: qsTr("Tools")
114
115        function createMenu(map)
116        {
117            clear()
118            if (map.plugin.supportsGeocoding(Plugin.ReverseGeocodingFeature)) {
119                addItem(qsTr("Reverse geocode")).triggered.connect(function(){selectTool("RevGeocode")})
120            }
121            if (map.plugin.supportsGeocoding()) {
122                addItem(qsTr("Geocode")).triggered.connect(function(){selectTool("Geocode")})
123            }
124            if (map.plugin.supportsRouting()) {
125                addItem(qsTr("Route with coordinates")).triggered.connect(function(){selectTool("CoordinateRoute")})
126                addItem(qsTr("Route with address")).triggered.connect(function(){selectTool("AddressRoute")})
127            }
128
129            var item = addItem("")
130            item.text = Qt.binding(function() { return isMiniMap ? qsTr("Hide minimap") : qsTr("Minimap") })
131            item.triggered.connect(function() {toggleMapState("MiniMap")})
132
133            item = addItem("")
134            item.text = Qt.binding(function() { return isFollowMe ? qsTr("Stop following") : qsTr("Follow me")})
135            item.triggered.connect(function() {toggleMapState("FollowMe")})
136
137            addItem(qsTr("Language")).triggered.connect(function(){selectTool("Language")})
138            addItem(qsTr("Prefetch Map Data")).triggered.connect(function(){selectTool("Prefetch")})
139            addItem(qsTr("Clear Map Data")).triggered.connect(function(){selectTool("Clear")})
140        }
141    }
142}
143