1/****************************************************************************
2**
3** Copyright (C) 2017 The Qt Company Ltd.
4** Contact: https://www.qt.io/licensing/
5**
6** This file is part of the examples of the Qt Toolkit.
7**
8** $QT_BEGIN_LICENSE:BSD$
9** Commercial License Usage
10** Licensees holding valid commercial Qt licenses may use this file in
11** accordance with the commercial license agreement provided with the
12** Software or, alternatively, in accordance with the terms contained in
13** a written agreement between you and The Qt Company. For licensing terms
14** and conditions see https://www.qt.io/terms-conditions. For further
15** information use the contact form at https://www.qt.io/contact-us.
16**
17** BSD License Usage
18** Alternatively, you may use this file under the terms of the BSD license
19** as follows:
20**
21** "Redistribution and use in source and binary forms, with or without
22** modification, are permitted provided that the following conditions are
23** met:
24**   * Redistributions of source code must retain the above copyright
25**     notice, this list of conditions and the following disclaimer.
26**   * Redistributions in binary form must reproduce the above copyright
27**     notice, this list of conditions and the following disclaimer in
28**     the documentation and/or other materials provided with the
29**     distribution.
30**   * Neither the name of The Qt Company Ltd nor the names of its
31**     contributors may be used to endorse or promote products derived
32**     from this software without specific prior written permission.
33**
34**
35** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
36** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
37** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
38** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
39** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
40** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
41** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
42** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
43** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
44** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
45** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
46**
47** $QT_END_LICENSE$
48**
49****************************************************************************/
50
51import QtQuick 2.0
52import "../flickrcommon" as Common
53
54Flipable {
55    id: container
56
57    property variant frontContainer: containerFront
58    property string photoTitle: ""
59    property string photoDate
60    property string photoUrl
61    property variant prevScale: 1.0
62
63    signal closed
64
65    transform: Rotation {
66        id: itemRotation
67        origin.x: container.width / 2;
68        axis.y: 1; axis.z: 0
69    }
70
71    front: Item {
72        id: containerFront; anchors.fill: container
73
74        Rectangle {
75            anchors.fill: parent
76            color: "black"; opacity: 0.4
77        }
78
79        Column {
80            spacing: 10
81            anchors {
82                left: parent.left; leftMargin: 20
83                right: parent.right; rightMargin: 20
84                top: parent.top; topMargin: 180
85            }
86            Text { font.bold: true; color: "white"; elide: Text.ElideRight; text: container.photoTitle }
87            Text { color: "white"; elide: Text.ElideRight; text: "<b>Published:</b> " + container.photoDate }
88        }
89    }
90
91    back: Item {
92        anchors.fill: container
93
94        Rectangle { anchors.fill: parent; color: "black"; opacity: 0.4 }
95
96        Common.Progress {
97            anchors.centerIn: parent; width: 200; height: 18
98            progress: bigImage.progress; visible: bigImage.status != Image.Ready
99        }
100
101        Flickable {
102            id: flickable; anchors.fill: parent; clip: true
103            contentWidth: imageContainer.width; contentHeight: imageContainer.height
104
105            Item {
106                id: imageContainer
107                width: Math.max(bigImage.width * bigImage.scale, flickable.width);
108                height: Math.max(bigImage.height * bigImage.scale, flickable.height);
109
110                Image {
111                    id: bigImage; // source: container.photoUrl
112                    source: container.photoUrl
113                    scale: slider.value
114                    anchors.centerIn: parent; smooth: !flickable.movingVertically
115                    onStatusChanged : {
116                        // Default scale shows the entire image.
117                        if (status == Image.Ready && width != 0) {
118                            slider.minimum = Math.min(flickable.width / width, flickable.height / height);
119                            prevScale = Math.min(slider.minimum, 1);
120                            slider.value = prevScale;
121                        }
122                    }
123                }
124            }
125        }
126
127        Text {
128            text: "Image Unavailable"
129            visible: bigImage.status == Image.Error
130            anchors.centerIn: parent; color: "white"; font.bold: true
131        }
132
133        Common.Slider {
134            id: slider; visible: { bigImage.status == Image.Ready && maximum > minimum }
135            anchors {
136                bottom: parent.bottom; bottomMargin: 65
137                left: parent.left; leftMargin: 25
138                right: parent.right; rightMargin: 25
139            }
140            onValueChanged: {
141                if (bigImage.width * value > flickable.width) {
142                    var xoff = (flickable.width/2 + flickable.contentX) * value / prevScale;
143                    flickable.contentX = xoff - flickable.width/2;
144                }
145                if (bigImage.height * value > flickable.height) {
146                    var yoff = (flickable.height/2 + flickable.contentY) * value / prevScale;
147                    flickable.contentY = yoff - flickable.height/2;
148                }
149                prevScale = value;
150            }
151        }
152    }
153
154    states: State {
155        name: "Back"
156        PropertyChanges { target: itemRotation; angle: 180 }
157    }
158
159    transitions: Transition {
160        SequentialAnimation {
161            PropertyAction { target: bigImage; property: "smooth"; value: false }
162            NumberAnimation { easing.type: Easing.InOutQuad; properties: "angle"; duration: 500 }
163            PropertyAction { target: bigImage; property: "smooth"; value: !flickable.movingVertically }
164        }
165    }
166}
167